Príklad 2 - Založenie novej firmy v adresári firiem

' Script spúšťať z konzoly cscript scriptname.vbs.

' Vytvorenie inštancie objektu, pomocou ktorého je možné písáť znaky do konzoly.
Set mStdOut = WScript.StdOut

' Definícia premenných. Toto nie je nutné vo vbsciptu robiť. Ohľadom práce s premennými platí nasledujúce dôležité pravidlo.
' Existující proměnné se nesmí používat pro jiný datový typ, než jakým byla proměnná inicializována.

Dim mApplication 
Dim FirmObject 
Dim FirmData 
Dim AddressData 
Dim BankAccountsCollection 
Dim BankAccountData 
Dim DealerCategoryQuery 
Dim DealerCategoryRowset 
Dim CodeConstraint 

' Prihlásenie
Set mApplication = CreateObject("AbraOLE.Application")
mApplication.LogIn "Supervisor", ""

' Vyrobenie novej firmy
Set FirmObject = mApplication.CreateObject("@Firm")
Set FirmData = mApplication.CreateValues("@Firm")

' Naplnenie názvu firmy
FirmObject.PrefillValues FirmData
FirmData.ValueByName("Name") = "Meno firmy"
' Naplnenie adresy
Set AddressData = FirmData.ValueByName("ResidenceAddress_ID")
AddressData.ValueByName("Street") = "Ulica"
' Naplnenie bankových účtov
Set BankAccountData = mApplication.CreateValues("@FirmBankAccount")
BankAccountData.ValueByName("BankAccount") = "12345"
Set BankAccountsCollection = FirmData.ValueByName("Rows")
BankAccountsCollection.Add BankAccountData

' Príklad použitia DynSQL
Set DealerCategoryQuery = mApplication.CreateCommand("DealerCategory")

' Získanie podmienky
Set CodeConstraint = DealerCategoryQuery.ConstraintByID("Code")

' Naplnenie podmienky
CodeConstraint.UsedKind = 1
CodeConstraint.Value = "'" & "1" & "'"

' Získanie hlavného rowsetu MAIN
Set DealerCategoryRowset = DealerCategoryQuery.RowsetByName("Main")
' Zaujíma nás stĺpec ID
DealerCategoryRowset.UsedFields = "ID" 
' Viac stĺpcov by sa napr. zadalo takto:
' DealerCategoryRowset.UsedFields = "ID" & vbCRLF & "Code"

' Vykonanie DynSQL, od teraz môžeme z použitých rowsetov čítať dáta.
DealerCategoryQuery.Execute
If Not DealerCategoryRowset.EOF Then
  FirmData.ValueByName("DealerCategory_ID") = DealerCategoryRowset.Data(0)
  ' Pokiaľ poznáme meno stĺpca v rowsete, môžeme použiť nasledujúcu konštrukciu...  
  ' FirmData.ValueByName("DealerCategory_ID") = _
  ' DealerCategoryRowset.Data.ValueByName("ID")
End If

' Uloženie firmy
FirmObject.CreateNewFromValues FirmData