Příklad 22 - Práce s obrázky skladové karty

Nasledujúce príklady popisujú prácu s triedou Picture. Použitá syntax zodpovedá prostrediu Windows Script.

Príklad pridá obrázok načítaný zo súboru na skladovú kartu.

  Dim G3 
  Dim StoreCardObject 
  Dim StoreCardData 
  Dim StoreCardPicturesCol 
  Dim StoreCardPictureData 
  Dim StoreCardPictureObject
  Dim PictureData
  const StoreCard_ID = "2100000101"

  ' Prihlásenie
  Set G3 = CreateObject("AbraOLE.Application")
  G3.Login "Supervisor", ""
  
  ' Načtení skladové karty
  Set StoreCardObject = G3.CreateObject("@StoreCard")
  Set StoreCardData = StoreCardObject.GetValues(StoreCard_ID)
  Wscript.Echo "Skladová karta Kód: " & StoreCardData.ValueByName("Code") 

  ' Získání kolekce obrázků
  Set StoreCardPicturesCol = StoreCardData.ValueByName("Pictures")
  
  ' Naplnění řádku kolekce obrázků skladové karty
  Set StoreCardPictureObject = G3.CreateObject("@StoreCardPicture")
  Set StoreCardPictureData = G3.CreateValues("@StoreCardPicture")
  StoreCardPictureObject.PrefillValues StoreCardPictureData
  
  ' Načtení obrázku ze souboru
  Set PictureData = StoreCardPictureData.ValueByName("Picture_ID")
  Set PictureObject = G3.CreateObject("@Picture")
  PictureObject.LoadFromFile PictureData, "c:\\AbraGen\\html\\books.jpg" 
  
  ' Přidání řádku s obrázkem do kolekce
  StoreCardPicturesCol.Add StoreCardPictureData  

  ' Uložení skladové karty
  StoreCardObject.UpdateValues StoreCard_ID, StoreCardData

Príklad načíta a uloží obrázky zo skladovej karty do súborov.

  Dim G3 
  Dim StoreCardObject 
  Dim StoreCardData 
  Dim StoreCardPicturesCol 
  Dim StoreCardPictureData 
  Dim StoreCardPictureObject
  Dim PictureData
  Dim ImageExt
  Dim ImageName
  const StoreCard_ID = "2100000101"

  ' Prihlásenie
  Set G3 = CreateObject("AbraOLE.Application")
  G3.Login "Supervisor", ""

  ' Načtení skladové karty
  Set StoreCardObject = G3.CreateObject("@StoreCard")
  Set StoreCardData = StoreCardObject.GetValues(StoreCard_ID)
  Wscript.Echo "Skladová karta Kód: " & StoreCardData.ValueByName("Code") 

  ' Získání kolekce obrázků
  Set StoreCardPicturesCol = StoreCardData.ValueByName("Pictures")
  For i = 0 To (StoreCardPicturesCol.Count - 1)
    Wscript.Echo "Ukládám obrázek " & i 
    Set StoreCardPictureData = StoreCardPicturesCol.Item(i)
    Set PictureData = StoreCardPictureData.ValueByName("Picture_ID")
    Set PictureObject = G3.CreateObject("@Picture")
    ImageExt = PictureObject.GetImageExt(PictureData) 
    ImageName = StoreCard_ID & "(" & i & ")"
    ' Uložení obrázku do souboru
    PictureObject.SaveToFile PictureData, "C:\\" & ImageName & ImageExt 
  Next

Príklad pridá externý obrázok na skladovú kartu.

  Dim G3 
  Dim StoreCardObject 
  Dim StoreCardData 
  Dim StoreCardPicturesCol 
  Dim StoreCardPictureData 
  Dim StoreCardPictureObject
  Dim PictureData
  const StoreCard_ID = "2100000101"

  ' Prihlásenie
  Set G3 = CreateObject("AbraOLE.Application")
  G3.Login "Supervisor", ""
 
  ' Načtení skladové karty
  Set StoreCardObject = G3.CreateObject("@StoreCard")
  Set StoreCardData = StoreCardObject.GetValues(StoreCard_ID)
  Wscript.Echo "Skladová karta Kód: " & StoreCardData.ValueByName("Code") 
  ' Získání kolekce obrázků
  Set StoreCardPicturesCol = StoreCardData.ValueByName("Pictures")
  
  ' Naplnění řádku kolekce obrázku skladové karty
  Set StoreCardPictureObject = G3.CreateObject("@StoreCardPicture")
  Set StoreCardPictureData = G3.CreateValues("@StoreCardPicture")
  StoreCardPictureObject.PrefillValues StoreCardPictureData
  
  ' Vyplnění parametrů externího obrázku
  Set PictureData = StoreCardPictureData.ValueByName("Picture_ID")
  Set PictureObject = G3.CreateObject("@Picture")
  PictureObject.PrefillValues PictureData
  PictureData.ValueByName("ExternalFile") = True
  PictureData.ValueByName("PictureTitle") = "Obrázek"
  PictureData.ValueByName("PathAndFileName") = "c:\\AbraGen\\html\\books.jpg" 
  
  ' Přidání řádku s obrázkem do kolekce
  StoreCardPicturesCol.Add StoreCardPictureData  

  ' Uložení skladové karty
  StoreCardObject.UpdateValues StoreCard_ID, StoreCardData